* Reference: Chapter 8 of
*   Ernst R. Berndt, The Practice of Econometrics, Addison-Wesley, 1991.
SAMPLE 1 49
READ (CIGAD) YEAR SALES SALESPC INCPC RPRICE CIGTOB TOBPC PRTOB DF &
 ASTOCK / SKIPLINES=1
READ (CIGAD) TIME ADV TOBADV REALAD TPERCIG ASTOCK1 ASTOCK2 F L &
 LNI / SKIPLINES=1 NOREWIND
* Data check
IF (YEAR.NE.(TIME+1900))
 STOP

* Exercise 7, p. 432.
*  (a)
GENR LNC=LOG(SALESPC)
GENR LNY=LOG(INCPC)
GENR LNP=LOG(RPRICE)
GENR LNA=LOG(ASTOCK)
GENR D53=(YEAR.GE.1953)
GENR D64=(YEAR.GE.1964)
* Allocate a variable for forecasts.
DIM LYHAT 49
* Equation (8.60)
SAMPLE 1 41
OLS LNC LNY LNP LNA DF D53 D64 / LOGLOG DWPVALUE
* Forecasting
FC / BEG=42 END=49 PREDICT=LYHAT
SAMPLE 49 49 
GENR YHAT=EXP(LYHAT)
GENR RATIO=100*(YHAT-SALESPC)/SALESPC
PRINT SALESPC YHAT RATIO
*  (b)
SAMPLE 1 49
GENR D71=(YEAR.GE.1971)
OLS LNC LNY LNP LNA DF D53 D64 D71 / LOGLOG DWPVALUE
*  Chow test for parameter stability.
*  Create slope dummy variables.
GENR DLNY=D71*LNY
GENR DLNP=D71*LNP
GENR DLNA=D71*LNA
OLS LNC LNY LNP LNA DF D53 D64 D71 DLNY DLNP DLNA
*  Calculate an F-test statistic
TEST
 TEST DLNY=0
 TEST DLNP=0
 TEST DLNA=0
END
TEST
 TEST DLNY=0
 TEST DLNP=0
 TEST DLNA=0
 TEST D71=0
END
*  (c) Estimate Equation (8.61)
GENR LCIGTOB=LOG(CIGTOB/100)
NL 1 / NCOEF=2 PREDICT=LNI0
EQ LCIGTOB = A + LOG(1 + 2*(YC/INCPC)) - 2*YC/INCPC
END
* With the NL command the standard errors are calculated by
* numerical methods.
*  (d) Compare the fitted values LNI0 with the fitted values LNI
*      provided in the CIGAD data file.
PRINT LNI0 LNI
GENR LNY2=LNY*LNY
STAT LNI0 LNY LNY2 / PCOR
OLS LNC LNY LNY2 LNP LNA DF D53 D64 D71 / DWPVALUE
STOP