* Reference: Chapter 10 of
*   Ernst R. Berndt, The Practice of Econometrics, Addison-Wesley, 1991.
* Use the TIME command to show annual data starting from 1920
TIME 1920 1
* Use the decimal point form of the SAMPLE command to show years
SAMPLE 1920. 1941.
READ (KLEIN) YEAR CN P W1 I KLAG E W2 G TX / SKIPLINES=1

* Exercise 1, p. 557.
*  (a) Variable transformations
GENR T=YEAR-1931
GENR W=W1+W2
GENR Y=CN+I+G-TX
GENR PLAG=LAG(P)
GENR ELAG=LAG(E)
*  (b) OLS regressions
SAMPLE 1921. 1941.
OLS CN W P PLAG / RSTAT
OLS I P PLAG KLAG / RSTAT
OLS W1 E ELAG T / RSTAT
*  (c) 2SLS regressions
2SLS CN W P PLAG (PLAG KLAG ELAG T TX G W2) / DN RSTAT
2SLS I P PLAG KLAG (PLAG KLAG ELAG T TX G W2) / DN RSTAT
2SLS W1 E ELAG T (PLAG KLAG ELAG T TX G W2) / DN RSTAT

* Exercise 7, p. 572.
*  (b) 3SLS estimation
SYSTEM 3 PLAG KLAG ELAG T TX G W2 / DN
OLS CN W P PLAG
OLS I P PLAG KLAG
OLS W1 E ELAG T
*  (c) Iterated 3SLS estimation
SYSTEM 3 PLAG KLAG ELAG T TX G W2 / DN ITER=50
OLS CN W P PLAG
OLS I P PLAG KLAG
OLS W1 E ELAG T
STOP