* Reference: Chapter 10 of
*   Ernst R. Berndt, The Practice of Econometrics, Addison-Wesley, 1991.
* Use the TIME command to indicate annual data starting in 1929
TIME 1929 1
* Use the decimal point form of the SAMPLE command to allow years
SAMPLE 1929. 1965.
* Read the file, skipping the heading.
READ (LUCAS) YR HW PGNP N POP QL RGNP U R / SKIPLINES=1

* Exercise 2, p. 558.
* The index variables have 1929=100. 
* Rescale the index variables -- for the log-transformed model,
* the rescaling will affect the intercept estimate.
GENR HW=HW/100
GENR PGNP=PGNP/100
GENR N=N/100
GENR POP=POP/100
GENR QL=QL/100
GENR RGNP=RGNP/100
* Generate the required variables
GENR Y1=LOG(N/POP)
GENR Y2=LOG(QL*N/RGNP)
GENR Y3=LOG(HW)
GENR Y4=LOG(HW/QL)
GENR X2=LOG(RGNP/POP)
GENR X3=LOG(QL)
GENR Y1LAG=LAG(Y1)
GENR Y2LAG=LAG(Y2)
GENR Y3LAG=LAG(Y3)
GENR ULAG=LAG(U)
SAMPLE 1930. 1965.
GENR X1=LOG(PGNP/LAG(PGNP))
GENR X4=LOG(RGNP/LAG(RGNP))
GENR Y5=LOG(HW/LAG(HW))

* (a) 2SLS estimation 
*   Equation (10.36)
2SLS Y1 Y3 Y3LAG X1 Y1LAG (X1 X2 X3 X4 Y1LAG Y2LAG Y3LAG) / RSTAT
*   Equation (10.37)
2SLS Y2 Y4 Y2LAG X4 (X1 X2 X3 X4 Y1LAG Y2LAG Y3LAG) / RSTAT
*   Equation (10.38) 
2SLS U X1 Y5 ULAG (X1 X2 X3 X4 Y1LAG Y2LAG Y3LAG) / RSTAT

* (b) Reduced form regression
OLS Y3 Y3LAG X1 X2 X3 Y2LAG X4 Y1LAG  / PREDICT=Y3FIT 
*     Second stage of 2SLS - labor supply equation (10.36)
OLS Y1 Y3FIT Y3LAG X1 Y1LAG / RSTAT

* (c) Alternative estimation approach for the other equations.
OLS Y4 Y3LAG X1 X2 X3 Y2LAG X4 Y1LAG  / PREDICT=Y4FIT 
*     Second stage of 2SLS - equation (10.37)     
OLS Y2 Y4FIT Y2LAG X4 / RSTAT
*     Inverted Phillips curve equation (10.38)
GENR Y5FIT=Y3FIT-Y3LAG
OLS U X1 Y5FIT ULAG / RSTAT
STOP