* Reference: Chapter 8 of
*   Ernst R. Berndt, The Practice of Econometrics, Addison-Wesley, 1991.
SAMPLE 1 50
READ (ORANGE) YEAR REV INC QTY CURADV AVEADV POP CPI / SKIPLINES=1

* Exercise 1, p. 417.
* Exclude the war years
SKIPIF (YEAR.GE.1942).AND.(YEAR.LE.1946)
*  (a)
GENR LNREV=LOG(REV)
GENR LNQTY=LOG(QTY)
GENR LNINC=LOG(INC)
GENR LNCADV=LOG(CURADV)
GENR LNAVAD=LOG(AVEADV)
*  Equation (8.52) and (8.53)
OLS LNREV LNQTY LNINC LNCADV LNAVAD / LOGLOG 
*  Estimate of the price elasticity - reported as the TEST VALUE by
*  the TEST command.
TEST 1/(LNQTY-1)
*  Estimate of beta - the income elasticity
TEST -LNINC/(LNQTY-1) 
*  Estimate of gamma - the short-run elasticity of demand.
TEST -LNCADV/(LNQTY-1)
*  Estimate of delta
TEST -LNAVAD/(LNQTY-1)
*  Estimate of the long-run elasticity of demand
TEST -(LNCADV+LNAVAD)/(LNQTY-1)  
*  (b)
GENR LPRI=LOG(REV/QTY)
OLS LPRI LNQTY LNINC LNCADV LNAVAD / LOGLOG 
TEST 1/(LNQTY-1)
TEST -LNINC/(LNQTY-1) 
TEST -LNCADV/(LNQTY-1)
TEST -LNAVAD/(LNQTY-1)
TEST -(LNCADV+LNAVAD)/(LNQTY-1)  
*  (d) Estimate a log-linear version of Equation (8.51).
OLS LNQTY LPRI LNINC LNCADV LNAVAD / LOGLOG
*  (e) Hausman specification test
GENR LNCPI=LOG(CPI)
* A reduced form OLS regression.
OLS LNQTY LNINC LNCADV LNAVAD LNCPI / PREDICT=LQTYFIT
OLS LNREV LNQTY LNINC LNCADV LNAVAD LQTYFIT / LOGLOG DN
* The test statistic is the t-statistic on the coefficient
* corresponding to the LQTYFIT variable. 
* At a 5% significance level, a p-value less than 0.05 suggests
* rejection of the null hypothesis that LNQTY and the error term
* are uncorrelated.
*  (f)
2SLS LPRI LNQTY LNINC LNCADV LNAVAD (LNINC LNCADV LNAVAD LNCPI) 
* Note that few if any 2SLS coefficients are statistically 
* significantly different from zero.
*  (g) The next estimation gives identical parameter estimates to
*      the 2SLS estimates.
OLS LPRI LQTYFIT LNINC LNCADV LNAVAD  
STOP