* Reference: Chapter 10 of
*   Ernst R. Berndt, The Practice of Econometrics, Addison-Wesley, 1991.
* Set the TIME command for quarterly data starting in 1953
TIME 1953 4
* Use the decimal point form of the SAMPLE command for the sample period.
SAMPLE 1953.1 1975.4
* Read the data, skip the headings
READ (TAYLOR) DATE POTGNP M1 GNPDEF GNP / SKIPLINES=1
* Generate a time index.
GENR TIME=TIME(0)

* Exercise 3, p. 561.
*  (a) Variable transformations.
GENR YDEV=LOG(GNP/POTGNP)
GENR RM1=LOG(M1/GNPDEF)
*  The next command uses the LAG function for a lead.
GENR INF=LOG(LAG(GNPDEF,-1)/GNPDEF)
GENR INFLAG=LAG(INF)
GENR YDEVLAG=LAG(YDEV)
GENR YDEVLAG2=LAG(YDEV,2)
GENR RM1LAG=LAG(RM1)
GENR ACCEL=INF-INFLAG
*  Get some sample descriptive statistics
*  Adjust the sample period to exclude the last observation that
*  is undefined for the INF variable.
SAMPLE 1953.1 1975.3
STAT YDEV RM1 INF
GRAPH YDEV INF / TIME LINEONLY
GRAPH RM1 / TIME LINEONLY 

*  (b) & (c) Information set IS(t-1) is:
*  M1 GNPDEF RM1 YDEF(t-1) YDEV(t-2) INF(t-1) and TIME
SAMPLE 1953.3 1975.3
*  Equation (10.45) - an estimated version is (10.60)
*  The next command is so long it needs a continuation line with &
2SLS YDEV YDEVLAG YDEVLAG2 RM1 RM1LAG INF TIME &
 (M1 GNPDEF RM1 RM1LAG YDEVLAG YDEVLAG2 INFLAG TIME)
*  Equation (10.46) - an estimated version is (10.61)
2SLS INF INFLAG YDEV (M1 GNPDEF RM1 RM1LAG YDEVLAG YDEVLAG2 INFLAG TIME)
*  Test the null hypothesis that the coefficient on INFLAG is one.
TEST INFLAG=1
*  Now impose the restriction that the coefficient on INFLAG is one.
2SLS ACCEL YDEV (M1 GNPDEF RM1 RM1LAG YDEVLAG YDEVLAG2 INFLAG TIME)

*  (d)
GENR M1LAG=LAG(M1)
GENR GNPDFLAG=LAG(GNPDEF)
GENR RM1LAG2=LAG(RM1,2)
GENR YDEVLAG3=LAG(YDEV,3)
GENR INFLAG2=LAG(INF,2)
* Define a list of instrumental variables
ZVAR: M1LAG GNPDFLAG RM1LAG RM1LAG2 YDEVLAG2 YDEVLAG3 INFLAG2 TIME
* Adjust the sample period
SAMPLE 1953.4 1975.3  
2SLS YDEV YDEVLAG YDEVLAG2 RM1 RM1LAG INF TIME ([ZVAR])
2SLS INF INFLAG YDEV ([ZVAR])
TEST INFLAG=1
2SLS ACCEL YDEV ([ZVAR])

*  (e) 3SLS Estimation
SAMPLE 1953.3 1975.3 
SYSTEM 2 M1 GNPDEF RM1 RM1LAG YDEVLAG YDEVLAG2 INFLAG TIME
OLS YDEV YDEVLAG YDEVLAG2 RM1 RM1LAG INF TIME 
OLS INF INFLAG YDEV
TEST INFLAG=1
* Impose the unity restriction on INFLAG
SYSTEM 2 M1 GNPDEF RM1 RM1LAG YDEVLAG YDEVLAG2 INFLAG TIME / RESTRICT
OLS YDEV YDEVLAG YDEVLAG2 RM1 RM1LAG INF TIME 
OLS INF INFLAG YDEV
RESTRICT INFLAG=1
END
STOP