* Reference: Chapter 3 of
*   Ernst R. Berndt, The Practice of Econometrics, Addison-Wesley, 1991.
SAMPLE 1 16
READ (TIO2) YEAR PROD CUMPROD UCOST DEFLATOR / SKIPLINES=1
* Exercise 1, p. 85.
* Deflate the data
GENR DUCOST=UCOST/(DEFLATOR/100)
*  (a)
GENR LNY=LOG(PROD)
GENR LNCP=LOG(CUMPROD)
GENR LNUC=LOG(DUCOST)
GRAPH DUCOST CUMPROD / LINEONLY
GRAPH LNUC LNCP / LINEONLY
*  (b) Estimate a simple learning curve, Equation (3.8)
OLS LNUC LNCP / LOGLOG 
* Confidence interval for the learning curve elasticity
* (the coefficient on LNCP)
CONFID LNCP

* Exercise 2, p. 86
*  Estimate the generalized learning curve, Equation (3.33).
*  The ANOVA option reports an F-test statistic for testing the
*  joint null hypothesis that both slope coefficients are
*  simultaneously equal to zero. 
OLS LNUC LNCP LNY / LOGLOG ANOVA
*  Recover an estimate of the returns-to-scale parameter - 
*  Equation (3.35) - reported as TEST VALUE by the TEST command.
TEST 1/(1+LNY)

* Exercise 7, p. 92
*  (a) Durbin-Watson test statistic
OLS LNUC LNCP / LOGLOG DWPVALUE
OLS LNUC LNCP LNY / LOGLOG DWPVALUE
*  (b) Iterative Cochrane-Orcutt estimation
AUTO LNUC LNCP / RSTAT LOGLOG 
AUTO LNUC LNCP LNY / RSTAT LOGLOG 

* Exercise 10, p. 94
*  Make room for a prediction.
DIM LNUC1 17 LNCP1 17 YHAT 17 FSE 17
SAMPLE 1 16
GENR LNUC1=LNUC
GENR LNCP1=LNCP
* For the prediction, set the level of cumulative production equal to
* twice that at the last historical observation.
SAMPLE 17 17
GEN1 XN=CUMPROD:16
PRINT XN
GENR LNCP1=LOG(2*XN)
SAMPLE 1 16
OLS LNUC1 LNCP1
* Use the FC command for prediction.
FC / BEG=17 END=17 LIST PREDICT=YHAT FCSE=FSE
* Construct a 95% confidence interval.
* Obtain the critical value.
GEN1 DF=$N-$K
GEN1 ALPHA=0.05/2
DISTRIB ALPHA / TYPE=T DF=DF INVERSE 
GEN1 TC=$CRIT
SAMPLE 17 17
GENR YUP=YHAT+TC*FSE
GENR YLOW=YHAT-TC*FSE
* Print the prediction interval
PRINT YLOW YUP
STOP